NAME

CGI::Header - Adapter for CGI::header() function

SYNOPSIS

  use CGI::Header;

  # CGI.pm-compatible HTTP header properties
  my $header = {
      -attachment => 'foo.gif',
      -charset    => 'utf-7',
      -cookie     => [ $cookie1, $cookie2 ], # CGI::Cookie objects
      -expires    => '+3d',
      -nph        => 1,
      -p3p        => [qw/CAO DSP LAW CURa/],
      -target     => 'ResultsWindow',
      -type       => 'image/gif'
  };

  # create a CGI::Header object
  my $h = CGI::Header->new( $header );

  # update $header
  $h->set( 'Content-Length' => 3002 );
  $h->delete( 'Content-Disposition' );
  $h->clear;

  $h->header; # same reference as $header

VERSION

This document referes to CGI::Header version 0.19.

DESCRIPTION

This module is a utility class to manipulate a hash reference received by the header() function provided by CGI.pm. This class is, so to speak, a subclass of Hash, while Perl5 doesn't provide a built-in class called Hash.

This module isn't the replacement of the function. Although this class implements as_string() method, the function should stringify the reference in most cases.

This module can be used in the following situation:

1. $header is a hash reference which represents CGI response headers

For example, CGI::Application implements header_add() method which can be used to add CGI.pm-compatible HTTP header properties. Instances of CGI applications often hold those properties.

  my $header = { -type => 'text/plain' };

2. Manipulates $header using CGI::Header

Since property names are case-insensitive, application developers have to normalize them manually when they specify header properties. CGI::Header normalizes them automatically.

  use CGI::Header;

  my $h = CGI::Header->new( $header );
  $h->set( 'Content-Length' => 3002 ); # add Content-Length header

  $header;
  # => {
  #     -type => 'text/plain',
  #     -content_length => '3002',
  # }

3. Passes $header to CGI::header() to stringify the variable

  use CGI;

  print CGI::header( $header );
  # Content-length: 3002
  # Content-Type: text/plain; charset=ISO-8859-1
  #

header() function just stringifies given header properties. This module can be used to generate PSGI-compatible header array references. See "EXAMPLES".

CLASS METHOD

$header = CGI::Header->new( { -type => 'text/plain', ... }[, \%ENV] )

Given a header hash reference, returns a CGI::Header object which holds a reference to the original given argument:

  my $header = { -type => 'text/plain' };
  my $h = CGI::Header->new( $header );
  $h->header; # same reference as $header

The object updates the reference when called write methods like set(), delete() or clear():

  # updates $header
  $h->set( 'Content-Length' => 3002 );
  $h->delete( 'Content-Disposition' );
  $h->clear;

You can also pass the reference to the hash which contains your current environment, preceded by the header hash reference:

  my $h = CGI::Header->new( $header, \%ENV );
  $h->env; # => \%ENV

NOTE: In this case, new() doesn't check whether property names of $header are normalized or not at all, and so you have to rehash() the header hash reference explicitly when you aren't sure that they are normalized.

$header = CGI::Header->new( -type => 'text/plain', ... )

It's roughly equivalent to:

  my $h = CGI::Header->new({ -type => 'text/plain', ... })->rehash;

Unlike rehash(), if a property name is duplicated, that property will be overwritten silently:

  my $h = CGI::Header->new(
      -Type        => 'text/plain',
      Content_Type => 'text/html'
  );

  $h->header->{-type}; # => "text/html"

In addition to CGI.pm-compatible HTTP header properties, you can specify '-env' property which represents your current environment:

  my $h = CGI::Header->new(
      -type => 'text/plain',
      -env  => \%ENV,
  );

  $h->header; # => { -type => 'text/plain' }
  $h->env;    # => \%ENV

$header = CGI::Header->new( $media_type )

A shortcut for:

  my $header = CGI::Header->new({ -type => $media_type });

INSTANCE METHODS

$hashref = $header->env

Returns the reference to the hash which contains your current environment. env() defaults to \%ENV. This module depends on the following elements of env():

  SERVER_PROTOCOL
  SERVER_SOFTWARE

$hashref = $header->header

Returns the header hash reference associated with this CGI::Header object. You can always pass the header hash to CGI::header() function to generate CGI response headers:

  print CGI::header( $header->header );

$self = $header->rehash

Rebuilds the header hash to normalize parameter names without changing the reference. Returns this object itself. If parameter names aren't normalized, the methods listed below won't work as you expect.

  my $h1 = $header->header;
  # => {
  #     '-content_type'   => 'text/plain',
  #     'Set-Cookie'      => 'ID=123456; path=/',
  #     'expires'         => '+3d',
  #     '-target'         => 'ResultsWindow',
  #     '-content-length' => '3002'
  # }

  $header->rehash;

  my $h2 = $header->header; # same reference as $h1
  # => {
  #     '-type'           => 'text/plain',
  #     '-cookie'         => 'ID=123456; path=/',
  #     '-expires'        => '+3d',
  #     '-target'         => 'ResultsWindow',
  #     '-content_length' => '3002'
  # }

Normalized parameter names are:

1. lowercased

  'Content-Length' -> 'content-length'

2. start with a dash

  'content-length' -> '-content-length'

3. use underscores instead of dashes except for the first character

  '-content-length' -> '-content_length'

CGI::header() also accepts aliases of parameter names. This module converts them as follows:

 '-content_type'  -> '-type'
 '-set_cookie'    -> '-cookie'
 '-cookies'       -> '-cookie'
 '-window_target' -> '-target'
 '-uri'           -> '-location'
 '-url'           -> '-location'

If a property name is duplicated, throws an exception:

  $header->header;
  # => {
  #     -Type        => 'text/plain',
  #     Content_Type => 'text/html',
  # }

  $header->rehash; # die "Property '-type' already exists"

$value = $header->get( $field )

$value = $header->set( $field => $value )

Get or set the value of the header field. The header field name ($field) is not case sensitive. You can use underscores as a replacement for dashes in header names.

  # field names are case-insensitive
  $header->get( 'Content-Length' );
  $header->get( 'content-length' );

The $value argument may be a plain string or a reference to an array of CGI::Cookie objects for the Set-Cookie header.

  $header->set( 'Content-Length' => 3002 );
  my $length = $header->get( 'Content-Length' ); # => 3002

  # $cookie1 and $cookie2 are CGI::Cookie objects
  $header->set( 'Set-Cookie' => [$cookie1, $cookie2] );
  my $cookies = $header->get( 'Set-Cookie' ); # => [ $cookie1, $cookie2 ]

$bool = $header->exists( $field )

Returns a Boolean value telling whether the specified field exists.

  if ( $header->exists('ETag') ) {
      ...
  }

$value = $header->delete( $field )

Deletes the specified field form CGI response headers. Returns the value of the deleted field.

  my $value = $header->delete( 'Content-Disposition' ); # => 'inline'

$self = $header->clear

This will remove all header fields.

$bool = $header->is_empty

Returns true if the header contains no key-value pairs.

  $header->clear;

  if ( $header->is_empty ) { # true
      ...
  }

$clone = $header->clone

Returns a copy of this CGI::Header object. It's identical to:

  my %copy = %{ $header->header }; # shallow copy
  my $clone = CGI::Header->new( \%copy, $header->env );

$filename = $header->attachment

$header->attachment( $filename )

Can be used to turn the page into an attachment. Represents suggested name for the saved file.

  $header->attachment( 'genome.jpg' );
  my $filename = $header->attachment; # => "genome.jpg"

In this case, the outgoing header will be formatted as:

  Content-Disposition: attachment; filename="genome.jpg"

@tags = $header->p3p_tags

$header->p3p_tags( @tags )

Represents P3P tags. The parameter can be an array or a space-delimited string. Returns a list of P3P tags. (In scalar context, returns the number of P3P tags.)

  $header->p3p_tags(qw/CAO DSP LAW CURa/);
  # or
  $header->p3p_tags( 'CAO DSP LAW CURa' );

  my @tags = $header->p3p_tags; # => ("CAO", "DSP", "LAW", "CURa")
  my $size = $header->p3p_tags; # => 4

In this case, the outgoing header will be formatted as:

  P3P: policyref="/w3c/p3p.xml", CP="CAO DSP LAW CURa"

$format = $header->expires

$header->expires( $format )

The Expires header gives the date and time after which the entity should be considered stale. You can specify an absolute or relative expiration interval. The following forms are all valid for this field:

  $header->expires( '+30s' ); # 30 seconds from now
  $header->expires( '+10m' ); # ten minutes from now
  $header->expires( '+1h'  ); # one hour from now
  $header->expires( 'now'  ); # immediately
  $header->expires( '+3M'  ); # in three months
  $header->expires( '+10y' ); # in ten years time

  # at the indicated time & date
  $header->expires( 'Thu, 25 Apr 1999 00:40:33 GMT' );

$header->nph

If set to a true value, will issue the correct headers to work with a NPH (no-parse-header) script.

  $header->nph( 1 );
  my $nph = $header->nph; # => 1

@fields = $header->field_names

Returns the list of distinct field names present in the header in a random order. The field names have case as returned by CGI::header().

  my @fields = $header->field_names;
  # => ( 'Set-Cookie', 'Content-length', 'Content-Type' )

$self = $header->each( \&callback )

Apply a subroutine to each header field in turn. The callback routine is called with two parameters; the name of the field and a value. If the Set-Cookie header is multi-valued, then the routine is called once for each value. Any return values of the callback routine are ignored.

  my @lines;
  $header->each(sub {
      my ( $field, $value ) = @_;
      push @lines, "$field: $value";
  });

  print join @lines, "\n";
  # Content-length: 3002
  # Content-Type: text/plain

@headers = $header->flatten

Returns pairs of fields and values.

  # $cookie1 and $cookie2 are CGI::Cookie objects
  my $header = CGI::Header->new( -cookie => [$cookie1, $cookie2] );

  $header->flatten;
  # => (
  #     "Set-Cookie" => "$cookie1",
  #     "Set-Cookie" => "$cookie2",
  #     ...
  # )

  $header->flatten(1);
  # => (
  #     "Set-Cookie" => $cookie1,
  #     "Set-Cookie" => $cookie2,
  #     ...
  # )

  $header->flatten(0);
  # => (
  #     "Set-Cookie" => [$cookie1, $cookie2],
  #     ...
  # )

$header->as_string

$header->as_string( $eol )

Returns the header fields as a formatted MIME header. The optional $eol parameter specifies the line ending sequence to use. The default is \015\012.

When valid multi-line headers are included, this method will always output them back as a single line, according to the folding rules of RFC 2616: the newlines will be removed, while the white space remains.

Unlike CGI.pm, when invalid newlines are included, this module removes them instead of throwing exceptions.

If $header->nph is true, the Status-Line will be added to the beginning of response headers automatically.

  $header->nph(1);

  $header->as_string;
  # HTTP/1.1 200 OK
  # Server: Apache/1.3.27 (Unix)
  # ...

TYING A HASH

  use CGI::Header;

  my $header = { -type => 'text/plain' };
  tie my %header => 'CGI::Header' => $header;

  # update $header
  $header{'Content-Length'} = 3002;
  delete $header{'Content-Disposition'};
  %header = ();

  tied( %header )->header; # same reference as $header

Above methods are aliased as follows:

  TIEHASH -> new
  FETCH   -> get
  STORE   -> set
  DELETE  -> delete
  CLEAR   -> clear
  EXISTS  -> exists
  SCALAR  -> !is_empty

You can also iterate through the tied hash:

  my @fields = keys %header;
  my @values = values %header;
  my ( $field, $value ) = each %header;

EXAMPLES

CONVERTING TO HTTP::Headers OBJECTS

  use CGI::Header;
  use HTTP::Headers;

  my @header_props = ( -type => 'text/plain', ... );
  my $h = HTTP::Headers->new( CGI::Header->new(@header_props)->flatten );
  $h->header( 'Content-Type' ); # => "text/plain"

CREATING PSGI-COMPATIBLE HEADER ARRAY REFERENCES

  use parent 'CGI::PSGI';
  use CGI::Header;
  use Plack::Util;

  sub psgi_header {
      my $self = shift;
      my @args = ref $_[0] eq 'HASH' ? %{ $_[0] } : @_;

      my $header = CGI::Header->new(
          -charset => $self->charset,
          @args,
          -env => $self->env,
      );

      $header->set( 'Pragma' => 'no-cache' ) if $self->cache;

      my $status = $header->delete('Status') || '200 OK';
      $status =~ s/\D*$//;

      if ( Plack::Util::status_with_no_entity_body($status) ) {
          $header->delete( $_ ) for qw( Content-Type Content-Length );
      }

      my @headers = $header->flatten;

      # remove the Server header
      splice @headers, 0, 2 if $header->nph;

      $status, \@headers;
  }

DEPENDENCIES

This module is compatible with CGI.pm 3.51 or higher.

LIMITATIONS

Since the following strings conflict with property names, you can't use them as field names ($field):

  "Attachment"
  "Charset"
  "Cookie"
  "Cookies"
  "NPH"
  "Target"
  "Type"

Content-Type

You can set the Content-Type header to neither undef nor an empty:

  # wrong
  $header->set( 'Content-Type' => undef );
  $header->set( 'Content-Type' => q{} );

Use delete() instead:

  $header->delete('Content-Type');

Date

If one of the following conditions is met, the Date header will be set automatically, and also the header field will become read-only:

  if ( $header->nph or $header->get('Set-Cookie') or $header->expires ) {
      my $date = $header->get('Date'); # => HTTP-Date (current time)
      $header->set( 'Date' => 'Thu, 25 Apr 1999 00:40:33 GMT' ); # wrong
      $header->delete('Date'); # wrong
  }

Expires

You can't assign to the Expires header directly because the following behavior will surprise us:

  # wrong
  $header->set( 'Expires' => '+3d' );

  my $value = $header->get('Expires');
  # => "Thu, 25 Apr 1999 00:40:33 GMT" (not "+3d")

Use expires() instead:

  $header->expires('+3d');

P3P

You can't assign to the P3P header directly:

  # wrong
  $header->set( 'P3P' => '/path/to/p3p.xml' );

CGI::header() restricts where the policy-reference file is located, and so you can't modify the location (/w3c/p3p.xml). You're allowed to set P3P tags using p3p_tags().

Server

If the following condition is met, the Server header will be set automatically, and also the header field will become read-only:

  if ( $header->nph ) {
      my $server = $header->get('Server');
      # => $header->env->{SERVER_SOFTWARE}

      $header->set( 'Server' => 'Apache/1.3.27 (Unix)' ); # wrong
      $header->delete( 'Server' ); # wrong
  }

BUGS

There are no known bugs in this module. Please report problems to ANAZAWA (anazawa@cpan.org). Patches are welcome.

AUTHOR

Ryo Anazawa (anazawa@cpan.org)

LICENSE

This module is free software; you can redistibute it and/or modify it under the same terms as Perl itself. See perlartistic.

To install CGI::Header, copy and paste the appropriate command in to your terminal.

cpanm

cpanm CGI::Header

CPAN shell

perl -MCPAN -e shell
install CGI::Header

For more information on module installation, please visit the detailed CPAN module installation guide.

	Global
`s`	Focus search bar
`?`	Bring up this help dialog

	GitHub
`g` `p`	Go to pull requests
`g` `i`	go to github issues (only if github is preferred repository)

	POD
`g` `a`	Go to author
`g` `c`	Go to changes
`g` `i`	Go to issues
`g` `d`	Go to dist
`g` `r`	Go to repository/SCM
`g` `s`	Go to source
`g` `b`	Go to file browse

	Search terms
module: (e.g. module:Plugin)
distribution: (e.g. distribution:Dancer auth)
author: (e.g. author:SONGMU Redis)
version: (e.g. version:1.00)