NAME

Mouse - Moose minus the antlers

SYNOPSIS

    package Point;
    use Mouse; # automatically turns on strict and warnings

    has 'x' => (is => 'rw', isa => 'Int');
    has 'y' => (is => 'rw', isa => 'Int');

    sub clear {
        my $self = shift;
        $self->x(0);
        $self->y(0);
    }

    package Point3D;
    use Mouse;

    extends 'Point';

    has 'z' => (is => 'rw', isa => 'Int');

    after 'clear' => sub {
        my $self = shift;
        $self->z(0);
    };

DESCRIPTION

Moose is wonderful. Use Moose instead of Mouse.

Unfortunately, Moose has a compile-time penalty. Though significant progress has been made over the years, the compile time penalty is a non-starter for some very specific applications. If you are writing a command-line application or CGI script where startup time is essential, you may not be able to use Moose. We recommend that you instead use HTTP::Engine and FastCGI for the latter, if possible.

Mouse aims to alleviate this by providing a subset of Moose's functionality, faster.

We're also going as light on dependencies as possible. Class::Method::Modifiers::Fast or Class::Method::Modifiers is required if you want support for "before", "after", and "around".

MOOSE COMPAT

Compatibility with Moose has been the utmost concern. Fewer than 1% of the tests fail when run against Moose instead of Mouse. Mouse code coverage is also over 96%. Even the error messages are taken from Moose. The Mouse code just runs the test suite 4x faster.

The idea is that, if you need the extra power, you should be able to run s/Mouse/Moose/g on your codebase and have nothing break. To that end, we have written Any::Moose which will act as Mouse unless Moose is loaded, in which case it will act as Moose. Since Mouse is a little sloppier than Moose, if you run into weird errors, it would be worth running:

    ANY_MOOSE=Moose perl your-script.pl

to see if the bug is caused by Mouse. Moose's diagnostics and validation are also much better.

MouseX

Please don't copy MooseX code to MouseX. If you need extensions, you really should upgrade to Moose. We don't need two parallel sets of extensions!

If you really must write a Mouse extension, please contact the Moose mailing list or #moose on IRC beforehand.

Maintenance

The original author of this module has mostly stepped down from maintaining Mouse. See http://www.nntp.perl.org/group/perl.moose/2009/04/msg653.html. If you would like to help maintain this module, please get in touch with us.

KEYWORDS

meta -> Mouse::Meta::Class

Returns this class' metaclass instance.

extends superclasses

Sets this class' superclasses.

before (method|methods) => Code

Installs a "before" method modifier. See "before" in Moose or "before" in Class::Method::Modifiers.

Use of this feature requires Class::Method::Modifiers!

after (method|methods) => Code

Installs an "after" method modifier. See "after" in Moose or "after" in Class::Method::Modifiers.

Use of this feature requires Class::Method::Modifiers!

around (method|methods) => Code

Installs an "around" method modifier. See "around" in Moose or "around" in Class::Method::Modifiers.

Use of this feature requires Class::Method::Modifiers!

has (name|names) => parameters

Adds an attribute (or if passed an arrayref of names, multiple attributes) to this class. Options:

is => ro|rw

If specified, inlines a read-only/read-write accessor with the same name as the attribute.

isa => TypeConstraint

Provides type checking in the constructor and accessor. The following types are supported. Any unknown type is taken to be a class check (e.g. isa => 'DateTime' would accept only DateTime objects).

    Any Item Bool Undef Defined Value Num Int Str ClassName
    Ref ScalarRef ArrayRef HashRef CodeRef RegexpRef GlobRef
    FileHandle Object

For more documentation on type constraints, see Mouse::Util::TypeConstraints.

required => 0|1

Whether this attribute is required to have a value. If the attribute is lazy or has a builder, then providing a value for the attribute in the constructor is optional.

init_arg => Str | Undef

Allows you to use a different key name in the constructor. If undef, the attribue can't be passed to the constructor.

default => Value | CodeRef

Sets the default value of the attribute. If the default is a coderef, it will be invoked to get the default value. Due to quirks of Perl, any bare reference is forbidden, you must wrap the reference in a coderef. Otherwise, all instances will share the same reference.

lazy => 0|1

If specified, the default is calculated on demand instead of in the constructor.

predicate => Str

Lets you specify a method name for installing a predicate method, which checks that the attribute has a value. It will not invoke a lazy default or builder method.

clearer => Str

Lets you specify a method name for installing a clearer method, which clears the attribute's value from the instance. On the next read, lazy or builder will be invoked.

handles => HashRef|ArrayRef

Lets you specify methods to delegate to the attribute. ArrayRef forwards the given method names to method calls on the attribute. HashRef maps local method names to remote method names called on the attribute. Other forms of "handles", such as regular expression and coderef, are not yet supported.

weak_ref => 0|1

Lets you automatically weaken any reference stored in the attribute.

Use of this feature requires Scalar::Util!

trigger => CodeRef

Any time the attribute's value is set (either through the accessor or the constructor), the trigger is called on it. The trigger receives as arguments the instance, the new value, and the attribute instance.

Mouse 0.05 supported more complex triggers, but this behavior is now removed.

builder => Str

Defines a method name to be called to provide the default value of the attribute. builder => 'build_foo' is mostly equivalent to default => sub { $_[0]->build_foo }.

auto_deref => 0|1

Allows you to automatically dereference ArrayRef and HashRef attributes in list context. In scalar context, the reference is returned (NOT the list length or bucket status). You must specify an appropriate type constraint to use auto_deref.

lazy_build => 0|1

Automatically define lazy => 1 as well as builder => "_build_$attr", clearer => "clear_$attr', predicate => 'has_$attr' unless they are already defined.

confess error -> BOOM

"confess" in Carp for your convenience.

blessed value -> ClassName | undef

"blessed" in Scalar::Util for your convenience.

MISC

import

Importing Mouse will default your class' superclass list to Mouse::Object. You may use "extends" to replace the superclass list.

unimport

Please unimport Mouse (no Mouse) so that if someone calls one of the keywords (such as "extends") it will break loudly instead breaking subtly.

FUNCTIONS

load_class Class::Name

This will load a given Class::Name (or die if it's not loadable). This function can be used in place of tricks like eval "use $module" or using require.

is_class_loaded Class::Name -> Bool

Returns whether this class is actually loaded or not. It uses a heuristic which involves checking for the existence of $VERSION, @ISA, and any locally-defined method.

SOURCE CODE ACCESS

We have a public git repo:

 git clone git://jules.scsys.co.uk/gitmo/Mouse.git

AUTHORS

Shawn M Moore, <sartak at gmail.com>

Yuval Kogman, <nothingmuch at woobling.org>

tokuhirom

Yappo

wu-lee

with plenty of code borrowed from Class::MOP and Moose

BUGS

There is a known issue with Mouse on 5.6.2 regarding the @ISA tests. Until this is resolve the minimum version of Perl for Mouse is set to 5.8.0. Patches to resolve these tests are more than welcome.

Please report any bugs through RT: email bug-mouse at rt.cpan.org, or browse http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Mouse.

COPYRIGHT AND LICENSE

Copyright 2008-2009 Infinity Interactive, Inc.

http://www.iinteractive.com/

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

cpanm Mouse

perl -MCPAN -e shell
install Mouse